1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
terraform {
  encryption {
    key_provider "external" "op" {
      command = ["./bin/tofu-state-key"]
    }

    method "aes_gcm" "op" {
      keys = key_provider.external.op
    }

    state {
      method   = method.aes_gcm.op
      enforced = true
    }

    plan {
      method   = method.aes_gcm.op
      enforced = true
    }
  }

  required_providers {
    dnsimple = {
      source  = "dnsimple/dnsimple"
      version = "~> 2.2"
    }

    linode = {
      source  = "linode/linode"
      version = "~> 4.7"
    }

    onepassword = {
      source  = "1Password/onepassword"
      version = "~> 3.3"
    }

    pihole = {
      source = "ryanwholey/pihole"

      # https://github.com/ryanwholey/terraform-provider-pihole/issues/86#issuecomment-2828469631
      version = "2.0.0-beta.1"
    }

    tailscale = {
      source  = "tailscale/tailscale"
      version = "~> 0.29.2"
    }
  }
}

provider "onepassword" {
  account = "alydipha.1password.com"
}

# Items are looked up by UUID: lookups by title fail with SDK return code -4.
locals {
  op_private_vault = "7escx6csroqkgfrmkpdubfrqoa"
}

# boxen-dnsimple
ephemeral "onepassword_item" "dnsimple" {
  vault = local.op_private_vault
  uuid  = "urxqkxvbav5m2trwhzgwkg43pu"
}

# boxen-linode
ephemeral "onepassword_item" "linode" {
  vault = local.op_private_vault
  uuid  = "wgyjufgbnzfv6h6jvqy7g632ma"
}

# boxen-pihole
ephemeral "onepassword_item" "pihole" {
  vault = local.op_private_vault
  uuid  = "xpf55644ii3azfcl74tywiagb4"
}

# boxen-tailscale
ephemeral "onepassword_item" "tailscale" {
  vault = local.op_private_vault
  uuid  = "zoaigxq4d3kg3heqgobxlg4hdu"
}

provider "dnsimple" {
  token   = ephemeral.onepassword_item.dnsimple.credential
  account = ephemeral.onepassword_item.dnsimple.username
}

provider "linode" {
  token = ephemeral.onepassword_item.linode.credential
}

provider "pihole" {
  url      = "http://mountain-of-faith:80"
  password = ephemeral.onepassword_item.pihole.credential
}

provider "tailscale" {
  tailnet             = "-"
  oauth_client_id     = ephemeral.onepassword_item.tailscale.username
  oauth_client_secret = ephemeral.onepassword_item.tailscale.credential
}

data "linode_instances" "ramble_hard" {
  filter {
    name   = "label"
    values = ["ramble-hard"]
  }
}

data "linode_instances" "lotus_land_story" {
  filter {
    name   = "label"
    values = ["lotus-land-story"]
  }
}

data "tailscale_device" "lotus_land_story" {
  hostname = "lotus-land-story"
}

data "tailscale_device" "mountain_of_faith" {
  hostname = "mountain-of-faith"
}

# Caddy's tsnet node for pro-tacts.
data "tailscale_device" "contacts" {
  hostname = "contacts"
}

locals {
  ramble_hard      = data.linode_instances.ramble_hard.instances.0
  lotus_land_story = data.linode_instances.lotus_land_story.instances.0
}

resource "pihole_dns_record" "domains" {
  for_each = {
    "git.kejadlen.dev" = data.tailscale_device.lotus_land_story.addresses.0
  }

  domain = each.key
  ip     = each.value
}

# doesn't seem to work
# resource "pihole_dns_record" "pi_hole" {
#   for_each = toset(["pi.hole"])
#
#   domain = each.key
#   ip     = data.tailscale_device.mountain_of_faith.addresses.0
# }